CURSOR II: ROWSET

Vamos a mostrar otra manera de recuperar registros de un cursor.
Partimos de una rutina que realiza un CURSOR a una tabla para recuperar todos los registros que cumplan una determinada condición.
Nuestra rutina devolverá la información recuperada al programa llamante a través de una tabla de 10 ocurrencias definida en la linkage.

Vamos con el ejemplo:
Imaginemos que la tabla a la que queremos acceder tiene estos datos:

Siendo CAMPO1 la clave.

En esta versión del uso de cursores mostraremos el uso de la sentencia ROWSET para recuperar los datos.
Trabajaremos con un cursor ROWSET POSITIONING. Este tipo de cursor nos permite recuperar uno o más registros en un solo FETCH.
Definimos un cursor del siguiente modo:

WORKING-STORAGE SECTION.

EXEC SQL
   DECLARE CURSOR CUR_TABLA ROWSET POSITIONING FOR
    SELECT CAMPO1,
           CAMPO2,
           CAMPO3,
           CAMPO4,
           CAMPO5
      FROM TABLA1
     WHERE CAMPO1 = :CLAVE-CAMPO1
     ORDER BY CAMPO1
END-EXEC

01 TBL-FETCH.
   05 TBL-CAMPO1 PIC XX OCCURS 100 TIMES.
   05 TBL-CAMPO2 PIC XX OCCURS 100 TIMES.
   05 TBL-CAMPO3 PIC XX OCCURS 100 TIMES.
   05 TBL-CAMPO4 PIC XX OCCURS 100 TIMES.
   05 TBL-CAMPO5 PIC XX OCCURS 100 TIMES.

01 HNUM-REGS PIC S9(9) COMP.

IMPORTANTE: La variable HNUM-REGS sera la variable HOST que indicará al FETCH cuantos registros queremos recuperar.
Esta variable tiene que ser binaria (tipo COMP) y además debe estar definida en el nivel de working 01.

En la linkage recibiremos la información de los campos clave.

LINKAGE SECTION.
01 ENTRADA.
   05 NUM-REGISTROS PIC 9(4).
   05 ENT-CAMPO1 PIC XX.
01 SALIDA.
   05 SAL-DATOS OCCURS 10 TIMES.
      10 SAL-CAMPO1 PIC XX.
      10 SAL-CAMPO2 PIC XX.
      10 SAL-CAMPO3 PIC XX.
      10 SAL-CAMPO4 PIC XX.
      10 SAL-CAMPO5 PIC XX.

En el inicio del programa informamos las variables de acceso al WHERE y realizaremos el OPEN del cursor:

INICIO

IF ENT-CAMPO1 EQUAL SPACES OR LOW-VALUES
   DISPLAY 'LA CLAVE ESTA VACIA'
   PERFORM 90000-FINAL
END-IF

MOVE ENT-CAMPO1 TO CLAVE-CAMPO1

Si no informa la variable número de registros la informamos con el número máximo de ocurrencias, en este caso 10.

IF NUM-REGISTROS EQUAL ZEROS OR LOW-VALUES
   MOVE 10 TO HNUM-REGS
ELSE
   MOVE NUM-REGISTROS TO HNUM-REGS
END-IF

EXEC SQL
   OPEN CUR_TABLA
END-EXEC

Controlaremos el SQLCODE. Si no fuese cero, tendríamos que dar un error.

IF SQLCODE NOT EQUAL ZEROES
   DISPLAY 'ERROR EN EL OPEN CURSOR. EL SQLCODE ES: 'SQLCODE
   PERFORM 90000-FINAL
END-IF

En el proceso realizamos un FECTH para recuperar todos los registros marcados por la variable de entrada NUM-REGISTROS(HNUM-REGS) en una tabla interna(TBL-FETCH).
A continuación volcamos la información de nuestra tabla interna en la tabla de salida:

PROCESO

EXEC SQL
   FETCH NEXT ROWSET CUR_TABLA FOR :HNUM-REGS ROWS
    INTO :TBL-CAMPO1,
         :TBL-CAMPO2,
         :TBL-CAMPO3,
         :TBL-CAMPO4,
         :TBL-CAMPO5
END-EXEC

Controlamos el SQLCODE devuelto:

EVALUATE TRUE
   WHEN SQLCODE EQUAL ZEROES
      DISPLAY 'TODO EN ORDEN'
   WHEN SQLCODE EQUAL +100 AND SQLERRD(3) > 0
      DISPLAY 'TODO EN ORDEN'
   WHEN SQLCODE EQUAL +100 AND SQLERRD(3) = 0
      DISPLAY 'NO ENCUENTRO NADA'
      PERFORM 90000-FINAL
   WHEN OTHER
      DISPLAY 'ALGO VA MAL. EL SQLCODE ES: 'SQLCODE
      PERFORM 90000-FINAL
END-EVALUATE

La variable de SQL SQLERRD(3) nos informa de cuantos registros se han recuperado en el FETCH (pudiese darse el caso de que nosotros quisiésemos recuperar 30 registros pero en la tabla sólo hubiese 10, el resultado del FETCH sería un SQLCODE=100 pero SQLERRD(3) > 0).
En nuestro caso el número de registros recuperados sería 6.

PERFORM UNTIL IND-REGISTROS GREATER SQLERRD(3)
   PERFORM GUARDAR-EN-SAL-DATOS
END-PERFORM

Al terminar, cerraremos el cursor:

EXEC SQL
   CLOSE CUR_TABLA
END-EXEC

Controlamos el SQLCODE. Si es distinto de cero daremos un error.

IF SQLCODE NOT EQUAL ZEROES
   DISPLAY 'ERROR CERRANDO CURSOR. EL SQLCODE ES: 'SQLCODE
END-IF

Según la tabla de nuestro ejemplo, habríamos guardado en SAL-DATOS todos los registros.

Para finalizar devolvemos el control al programa llamante.

FINAL

GOBACK.

La sentencia ROWSET de DB2 se puede usar con otras instrucciones SQL. Se puede usar con el INSERT / UPDATE / DELETE.
Si alguien está interesado en conocer más sobre el tema, que pregunte sin compromiso : )

Os dejo el programa de ejemplo para descargar.

Programas con DB2 II: CURSOR.

Listado: CURSOR.

Una rutina de listado realiza un CURSOR a una tabla para recuperar todos los registros que cumplan una determinada condición.
Nuestra rutina devolverá la información recuperada al programa llamante a través de una tabla interna definida en la linkage. Esta tabla tendrá un número de ocurrencias OCCURS que puede ser menor que el número de registros recuperados por el cursor.
Tendremos que tener en cuenta todo esto a la hora de codificar el programa.

Vamos con el ejemplo:
Imaginemos que la tabla a la que queremos acceder tiene estos datos:

Siendo CAMPO1 + CAMPO2 la clave.

Definiremos un cursor del siguiente modo:

WORKING-STORAGE SECTION.

EXEC SQL
   DECLARE CURSOR CUR_TABLA FOR
    SELECT CAMPO1,
           CAMPO2,
           CAMPO3,
           CAMPO4,
           CAMPO5
      FROM TABLA1
     WHERE CAMPO1 = :CLAVE-CAMPO1
       AND CAMPO2 > :CLAVE-CAMPO2
     ORDER BY CAMPO1, CAMPO2
END-EXEC

En la linkage recibiremos la información de los campos clave.

LINKAGE SECTION.
01 ENTRADA.
   05 ENT-CAMPO1 PIC XX.
   05 ENT-CAMPO2 PIC XX.
01 SALIDA.
   05 SAL-ULTIMA-CLAVE PIC XXXX.
   05 SAL-RECONSULTAR PIC X.
   05 SAL-DATOS OCCURS 5 TIMES.
      10 SAL-CAMPO1 PIC XX.
      10 SAL-CAMPO2 PIC XX.
      10 SAL-CAMPO3 PIC XX.
      10 SAL-CAMPO4 PIC XX.
      10 SAL-CAMPO5 PIC XX.

En el inicio del programa informaremos las variables de acceso al WHERE, realizaremos el OPEN del cursor y un primer FETCH. Podemos poner una validación del campo clave, para comprobar que trae datos, y en caso de no ser así finalizar la ejecución.

INICIO

IF ENT-CAMPO1 EQUAL SPACES OR LOW-VALUES
   DISPLAY 'LA CLAVE ESTA VACIA'
   PERFORM 90000-FINAL
END-IF

MOVE ENT-CAMPO1 TO CLAVE-CAMPO1
MOVE ENT-CAMPO2 TO CLAVE-CAMPO2

EXEC SQL
   OPEN CUR_TABLA
END-EXEC

Controlaremos el SQLCODE. Si no fuese cero, tendríamos que dar un error.

IF SQLCODE NOT EQUAL ZEROES
   DISPLAY 'ERROR EN EL OPEN CURSOR. EL SQLCODE ES: 'SQLCODE
   PERFORM 90000-FINAL
END-IF

EXEC SQL
   FETCH CUR_TABLA
    INTO :TABLA1-CAMPO1,
         :TABLA1-CAMPO2,
         :TABLA1-CAMPO3,
         :TABLA1-CAMPO4,
         :TABLA1-CAMPO5
END-EXEC

Controlamos el SQLCODE devuelto:

EVALUATE TRUE
   WHEN SQLCODE EQUAL ZEROES
      DISPLAY 'TODO EN ORDEN'
   WHEN SQLCODE EQUAL +100
      DISPLAY 'NO ENCUENTRO NADA'
      PERFORM 90000-FINAL
   WHEN OTHER
      DISPLAY 'ALGO VA MAL. EL SQLCODE ES: 'SQLCODE
      PERFORM 90000-FINAL
END-EVALUATE

SÓLO si el primer FETCH que realizamos nos devuelve un SQLCODE +100 quiere decir que no hay ningún registro con la clave que hemos introducido.
En posteriores FETCH, un SQLCODE +100 significa que YA NO HAY MÁS registros para esa clave.

En el proceso realizaremos un bucle para ir guardando la información devuelta por el cursor en nuestra tabla SAL-TABLA, e ir haciendo sucesivos FETCH hasta que recupere todos o el máximo de OCCURS de nuestra tabla interna:

PROCESO

PERFORM UNTIL SQLCODE EQUAL +100 OR IND-REGISTROS GREATER 5
   PERFORM GUARDAR-EN-SAL-TABLA

   PERFORM HAGO-OTRO-FETCH
END-PERFORM

Si salimos del bucle por la condición de SQLCODE = +100 informaremos el campo SAL-RECONSULTAR con una 'N' y el campo SAL-ULTIMA-CLAVE con espacios, pues ya hemos recuperado todos los registros que había en la tabla.

Si salimos del bucle por la condición de IND-REGISTROS > 5 informaremos el campo SAL-RECONSULTAR con una 'S' y el campo SAL-ULTIMA-CLAVE con los campos clave CAMPO1 y CAMPO2.

En cualquiera de los dos casos, cerraremos el cursor:

EXEC SQL
   CLOSE CUR_TABLA
END-EXEC

Controlamos el SQLCODE. Si es distinto de cero daremos un error.

IF SQLCODE NOT EQUAL ZEROES
   DISPLAY 'ERROR CERRANDO CURSOR. EL SQLCODE ES: 'SQLCODE
END-IF

Según la tabla de nuestro ejemplo, habríamos guardado en SAL-TABLA los registros:

Por lo que nos faltaría por recuperar un último registro. El campo SAL-ULTIMA-CLAVE valdría 'AAFF'.

Para finalizar devolvemos el control al programa llamante.
FINAL

GOBACK.

La siguiente vez que entrásemos al programa accederíamos al cursor con CAMPO1 = 'AA' y CAMPO2 = 'FF' y recuperaríamos el registro que falta:

Os dejo el código completo de un programa de ejemplo para descargar.

Nota: En respuesta a la sugerencia de Jose Antonio, hemos creado un nuevo artículo explicando el uso del ROWSET en los cursores.

Programas con DB2 I: SELECT, INSERT, UPDATE y DELETE.

En la mayoría de aplicaciones existirán, para cada tabla, una serie de rutinas con los diferentes tipos de accesos: consulta, lista, alta, modificación y baja.
Esto se traduce en SQL como: SELECT, CURSOR, INSERT, UPDATE y DELETE.
En este artículo vamos a "construir" cuatro de ellos; dejaremos la rutina de lista para explicar en un artículo aparte.

Este tipo de rutinas serán llamadas desde otros programas, ya sean BATCH u ONLINE. Tendrán definidas en la LINKAGE SECTION los campos a través de los cuales intercambiarán información con el programa llamante. Estos campos pueden venir definidos dentro de COPYs.

Consulta: SELECT.

Se trata del caso más sencillo en el que sólo queremos recuperar 1 registro de la tabla.

Vamos a ver un ejemplo:
LINKAGE SECTION
01 ENTRADA.
   05 CLAVE-SELECT PIC X(10).
01 SALIDA.
   05 SAL-CAMPO1 PIC X(10).
   05 SAL-CAMPO2 PIC X.
   05 SAL-PRI-CAMPO3 PIC XX.
   05 SAL-SEC-CAMPO3 PIC XX.
(...)
Los campos de entrada de la linkage contendrán la información enviada por el programa llamante. En este caso la clave por la que queremos acceder a nuestra SELECT.

En el inicio del programa podemos poner una validación del campo clave, para comprobar que trae datos, y en caso de no ser así finalizar la ejecución.
INICIO

IF CLAVE-SELECT EQUAL SPACES OR LOW-VALUES
   DISPLAY 'LA CLAVE VIENE VACIA'
   PERFORM 90000-FINAL
END-IF

Realizaremos la SELECT:

EXEC SQL
   SELECT CAMPO1,
          CAMPO2,
          PRI_CAMPO3,
          SEC_CAMPO3
     INTO :TABLA1-CAMPO1,
          :TABLA1-CAMPO2,
          :TABLA1-PRI-CAMPO3,
          :TABLA1-SEC-CAMPO3
     FROM TABLA1
    WHERE CAMPO1 = :CLAVE-SELECT
    ORDER BY CAMPO1
END-EXEC

Los campos que van en el apartado de SELECT son los campos de la tabla. Se escribirán del mismo modo en el que estén en el CREATE de la tabla. Se utilizará siempre el guión bajo.
Ocurre lo mismo en el apartado de ORDER BY.

Los campos que van en el apartado de INTO son variables HOST definidas en la WORKING del programa. Podemos nombrarlos como queramos. Siempre irán precedidos por los dos puntos ":". Se utilizará siempre el guión alto.
Ocurre lo mismo para los campos utilizados en el apartado de WHERE.
En caso de que tengamos campos numéricos, siempre irán definidos como signados y comprimidos (S9(X) COMP-3).

La variable HOST utilizada en el WHERE no deberá tener niveles inferiores. En caso de que así sea, deberemos utilizar un REDEFINES o moverla a otra variable:
01 CLAVE-SELECT.
   05 PARTE1 PIC X(5).
   05 PARTE2 PIC X(5).
01 CLAVE-ENTERA REDEFINES CLAVE-SELECT PIC X(10).
O bien:
01 CLAVE-SELECT.
   05 PARTE1 PIC X(5).
   05 PARTE2 PIC X(5).
01 CLAVE-ENTERA PIC X(10).
(...)
MOVE CLAVE-SELECT TO CLAVE-ENTERA

Puede darse el caso de que el campo del WHERE no sea una clave única de la tabla, y que la SELECT nos recupere más de un registro.
Si sólo queremos saber que existe "alguno" que cumple la condición, podemos solventar este problema añadiendo a la SELECT la sentencia FETCH FIRST ROW ONLY:

EXEC SQL
   SELECT CAMPO1,
          CAMPO2,
          PRI_CAMPO3,
          SEC_CAMPO3
     INTO :TABLA1-CAMPO1,
          :TABLA1-CAMPO2,
          :TABLA1-PRI-CAMPO3,
          :TABLA1-SEC-CAMPO3
     FROM TABLA1
    WHERE CAMPO1 = :CLAVE-SELECT
    ORDER BY CAMPO1
    FETCH FIRST ROW ONLY
END-EXEC

De este modo aunque recupere más de un registro no dará error, y nos devolverá el primero que encuentre.
Si no lo hiciésemos la consulta devolvería un SQLCODE = -811.

Una vez codificada la SELECT validaremos el código SQL que nos devuelve para comprobar que todo ha ido bien:

EVALUATE TRUE
   WHEN SQLCODE EQUAL ZEROES
      DISPLAY 'TODO VA BIEN'
   WHEN SQLCODE EQUAL +100
      DISPLAY 'NO ENCONTRE NADA'
   WHEN OTHER
      DISPLAY 'ALGO HA IDO MAL. EL SQLCODE ES: 'SQLCODE
      PERFORM 90000-FINAL
END-EVALUATE

Si la SELECT nos devuelve un SQLCODE distinto de cero y de 100, lo normal es finalizar la ejecución del programa.

Una vez comprobado que todo ha ido bien, informaremos los campos de SALIDA con la información recuperada de la SELECT:
MOVE TABLA1-CAMPO1     TO SAL-CAMPO1
MOVE TABLA1-CAMPO2     TO SAL-CAMPO2
MOVE TABLA1-PRI-CAMPO3 TO SAL-PRI-CAMPO3
MOVE TABLA1-SEC-CAMPO3 TO SAL-SEC-CAMPO3

En el párrafo de final devolveremos el control al programa llamante:
FINAL

GOBACK.

Y se terminó nuestra rutina de consulta : )

Alta: INSERT.

Cuando queremos dar de alta/insertar un registro en una tabla, tendremos que informar un mínimo de campos de la tabla(se deben informar al menos aquellos que pertenezcan a la clave única).
Estos campos vendrán informados desde el programa llamante y los recibiremos en la linkage.

Veamos un ejemplo:
LINKAGE SECTION.
01 ENTRADA.
   05 ENT-CAMPO1 PIC X(10).
   05 ENT-CAMPO2 PIC X.
   05 ENT-PRI-CAMPO3 PIC XX.
   05 ENT-SEC-CAMPO3 PIC XX.

En el inicio del programa podemos poner una validación de los campos obligatorios, para comprobar que vienen informados, y en caso de no ser así finalizar la ejecución.

Informaremos las variables HOST con las que realizaremos el INSERT:
MOVE ENT-CAMPO1     TO TABLA1-CAMPO1
MOVE ENT-CAMPO2     TO TABLA1-CAMPO2
MOVE ENT-PRI-CAMPO3 TO TABLA1-PRI-CAMPO3
MOVE ENT-SEC-CAMPO3 TO TABLA1-SEC-CAMPO3

Realizamos el INSERT:
EXEC SQL
   INSERT INTO TABLA1
         (CAMPO1,
          CAMPO2,
          PRI_CAMPO3,
          SEC_CAMPO3)
   VALUES(:TABLA1-CAMPO1,
          :TABLA1-CAMPO2,
          :TABLA1-PRI-CAMPO3,
          :TABLA1-SEC-CAMPO3)
END-EXEC

Es importante colocar los campos definidos en VALUES en el orden correcto.

Ahora validaremos el SQLCODE devuelto para comprobar que todo ha ido bien:
EVALUATE TRUE
   WHEN SQLCODE EQUAL ZEROES
      DISPLAY 'TODO HA IDO BIEN'
   WHEN SQLCODE EQUAL -803
      DISPLAY 'EL REGISTRO YA EXISTE EN LA TABLA'
   WHEN OTHER
      DISPLAY 'LA HEMOS LIAO PARDA. EL SQLCODE ES: 'SQLCODE
      PERFORM 90000-FINAL
END-EVALUATE

Una vez comprobado que todo ha ido bien, devolveremos el control al programa llamante:
FINAL
GOBACK.

Modificación: UPDATE.

Puede ocurrir que queramos modificar un solo campo o todos. Si no sabemos qué campos van a venir modificados lo normal es actualizarlos todos. Para ello debemos haber recuperado previamente toda la información del registro, o podríamos estar actualizando algunos campos con ceros o espacios.

En una rutina de modificación ONLINE se debe controlar siempre el TIMESTAMP de modificación del registro, para asegurarnos que no ha sido modificado mientras nosotros lo estábamos visualizando.

Veamos el ejemplo:
LINKAGE SECTION.
01 ENTRADA.
   05 ENT-CAMPO1 PIC X.
   05 ENT-CAMPO2 PIC X.
   05 ENT-CAMPO3 PIC XX.
   05 ENT-CAMPO4 PIC XX.
   05 ENT-TIMESTAMP PIC X(26).

La información de la linkage la habrá obtenido el programa llamante realizando una consulta del registro y con la información de los campos modificados.

Antes de realizar el UPDATE realizaremos una nueva consulta del registro:

EXEC SQL
   SELECT CAMPO1,
          TIMESTAMP
     INTO :TABLA2-CAMPO1,
          :TABLA2-TIMESTAMP
     FROM TABLA2
    WHERE CAMPO1 = :ENT-CAMPO1
    ORDER BY CAMPO1
END-EXEC

Validaremos el SQLCODE devuelto.
Si todo ha ido bien:
Compararemos el TIMESTAMP obtenido en TABLA2-TIMESTAMP con el recibido por linkage.
Recordad que un campo timestamp tiene este aspecto: 'AAAA-MM-DD-HH.MM.SS.MMMMMM'
Donde:
AAAA: año
MM: mes
DD: día
HH: hora
MM: minutos
SS: segundos
MMMMMM: milésimas de segundo

2010-12-01-22.15.01.012345

En total 26 posiciones.

IF ENT-TIMESTAMP NOT EQUAL TABLA2-TIMESTAMP
   DISPLAY 'ERROR: REGISTRO MODIFICADO POR OTRO USUARIO'
   PERFORM 90000-FINAL
END-IF

Esto significa que mientras nosotros visualizábamos el registro, otra persona lo modificó.
En caso de que los TIMESTAMP coincidan, informaremos las variables HOST del update con la información recibida por linkage.
MOVE ENT-CAMPO1 TO TABLA2-CAMPO1
MOVE ENT-CAMPO2 TO TABLA2-CAMPO2
MOVE ENT-CAMPO3 TO TABLA2-CAMPO3
MOVE ENT-CAMPO4 TO TABLA2-CAMPO4

Procederemos a hacer el UPDATE:

EXEC SQL
   UPDATE TABLA2
      SET (CAMPO2 = :TABLA2-CAMPO2,
           CAMPO3 = :TABLA2-CAMPO3,
           CAMPO4 = :TABLA2-CAMPO4,
           TIMESTAMP = CURRENT TIMESTAMP)
    WHERE CAMPO1 = :TABLA2-CAMPO1
END-EXEC

Tened en cuenta que no se deben modificar los campos de la tabla que pertenezcan a la clave única.

Validaremos el SQLCODE devuelto.
EVALUATE TRUE
   WHEN SQLCODE EQUAL ZEROES
      DISPLAY 'TODO HA IDO BIEN'
   WHEN SQLCODE EQUAL +100
      DISPLAY 'EL REGISTRO QUE SE QUIERE MODIFICAR NO EXISTE'
   WHEN OTHER
      DISPLAY 'YA LA HEMOS VUELTO A LIAR. EL SQLCODE ES: 'SQLCODE
      PERFORM 90000-FINAL
END-EVALUATE

Y devolveremos el control al programa llamante.

Puede darse el caso de que queramos modificar algún campo de la clave del registro. Normalmente para que pueda hacerse debe existir un campo clave o ISN a mayores que será numérico y autoincrementable y que identificará inequívocamente cada registro de la tabla.
Por ejemplo:

Donde CAMPO1 será el índice único y CLAVE la clave autoincrementable.
Ahora podríamos modificar el campo CAMPO1 accediendo a la tabla por el campo CLAVE.
Por ejemplo, si queremos modificar el campo CAMPO1 del registro con CLAVE = 14:
MOVE '5'  TO CAMPO1
MOVE 'X'  TO CAMPO2
MOVE 'YY' TO CAMPO3
MOVE 'ZZ' TO CAMPO4

EXEC SQL
   UPDATE TABLA2
     SET (CAMPO1 = :TABLA2-CAMPO1,
          CAMPO2 = :TABLA2-CAMPO2,
          CAMPO3 = :TABLA2-CAMPO3,
          CAMPO4 = :TABLA2-CAMPO4,
          TIMESTAMP = CURRENT TIMESTAMP)
    WHERE CLAVE = :TABLA2-CLAVE
END-EXEC

y el registro con CLAVE =14 quedaría:

Baja: DELETE.

Este tipo de baja también se denomina "baja física", en contraste con la "baja lógica", donde el registro no se borra, sino que se actualiza un campo "estado" indicando que el registro en cuestión "está de baja" ^^.

Para realizar un DELETE sólo necesitaremos el valor del campo clave del registro que queremos eliminar.

LINKAGE SECTION
01 ENTRADA.
   05 CAMPO-CLAVE PIC X.
(...)

EXEC SQL
   DELETE FROM TABLA3
    WHERE CAMPO1 = :CAMPO-CLAVE
END-EXEC

Validaremos el SQLCODE devuelto y devolveremos el control al programa llamante.

Os dejo los enlaces a los ejemplos completos de SELECT, INSERT, UPDATE y DELETE.